(****
 *
 * Module File defines the objects and operations related to file processing
 * in the Grader system.
 *
 *)

module File;

  from Spreadsheet import Gradesheet, StudentInfo, GradedItem, UserWorkSpace, RequiresSaving;
  export FileSpace, File;

  object FileSpace is File*
    description: (*
        A FileSpace is an abstract model of a file space in the operating
        environment in which the Grader Tool is run.  The FileSpace is simply
        a collection of zero or more Files, with no other properties modeled
        here.
     *);
  end;

  object File is
    components: name:FileName and permissions:FilePermissions and
        file_type:FileType and data:FileData;
    description: (*
        A File is an abstraction of a file stored in the file space.  It has a
        name, permissions, type, and data.  These are the components sufficient
        to specify the behavior of Grader Tool file operations.
    *);
  end File;

  object FileName is string
    description: (*
        The name of a file.  The string representation here is an abstraction
        of file names used in specific operating environments.  Implementations
        may obey any syntactic or semantic constraints imposed by a particular
        environment.
    *);
  end;

  object FilePermissions is is_readable:IsReadable and is_writable:IsWritable
    description: (*
        FilePermissions indicate whether a file is readable and/or writable.
    *);
  end;

  object IsReadable is boolean
    description: (*
        Flag indicating whether a file is readable, which is required to be
        true by the FileOpen operation.
    *);
  end;

  object IsWritable is boolean
    description: (*
        Flag indicating whether a file is writable, which is required to be
        true by the FileSave operation.
    *);
  end;

  object FileType is grader_type:GraderType or other_type:OtherType
    description: (*
        The type of file data is either GraderType data (which we care about)
        or any other type of data that can be stored in a file, which we don't
        care about.
    *);
  end FileType;

  object GraderType
    description: (*
        File data typing tag indicating that a file contains grader data
        created by the Grader Tool
    *);
  end GraderType;

  object OtherType
    description: (*
        File data typing tag indicating that a file contains data other than
        grader data created by the Grader Tool
    *);
  end OtherType;

  object FileData is Gradesheet
    description: (*
        The abstract representation of grader-type FileData is a gradesheet
        object.  Grader Tool implementors may use any concrete file data
        representation that accurately holds all gradesheet components.
    *);
  end FileData;

  operation FileNew is
    inputs: uws:UserWorkSpace;
    outputs: uws':UserWorkSpace;

    description: (*
        Add a new empty grader to the workspace and make it current.
    *);

    precondition: ;

    postcondition:
        (*
         * The output workspace has a new empty grader and that grader is
         * current.  The file is empty and the gradesheet does not require
	 * saving.  The gradesheets in positions 1-last in the the input
	 * workspace are in positions 2-last+1 in the output workspace.
         *)
        (exists (uc:Gradesheet)
            (uc = uws'.Gradesheets[1]) and
            (not uc.requires_saving) and
            (uc.items = nil) and
            (#(uws'.Gradesheets) = #(uws.Gradesheets) +1) and
            (forall (i:integer | (i >= 2) and (i <= #(uws.Gradesheets)))
                uws'.Gradesheets[i+1] = uws.Gradesheets[i+1]
            )
        );

  end FileNew;

  operation FileOpen is
    inputs: fs:FileSpace, fn:FileName, uws:UserWorkSpace;
    outputs: fs':FileSpace, uws':UserWorkSpace;

    description: (*
        Open an existing grader file of the given name and put the data from
        that file in the workspace.
    *);

    precondition:
        (*
         * A file of the given name exists in the given file space, the file
         * is readable, and the file's data are of type grader.
         *)
        exists (file in fs)
            (file.name = fn) and
            file.permissions.is_readable and
            file.file_type?grader_type;

    postcondition:
        (*
         * The output workspace has a new gradesheet containing the file data of
         * the input file, and that gradesheet is current.  The gradesheet does
	 * not require saving.  The calendars in positions 1-last in the the input
	 * workspace are in positions 2-last+1 in the output workspace.
         *)
        (exists (uc:Gradesheet)
            (uc = uws'.Gradesheets[1]) and
            (uc.uid = uws.uid) and
            (exists (file in fs)
                (file.name = fn) and
                (uc.file = file) and
                (uc.items = file.data.items)
            ) and
            (not uc.requires_saving) and
            (#(uws'.Gradesheets) = #(uws.Gradesheets) +1) and
            (forall (i:integer | (i >= 2) and (i <= #(uws.Gradesheets)))
                uws'.Gradesheets[i+1] = uws.Gradesheets[i+1]
            )
        );

  end FileOpen;

  operation FileClose is
    inputs: fs:FileSpace, uws:UserWorkSpace;
    outputs: fs':FileSpace, uws':UserWorkSpace;

    description: (*
        Close the current gradesheet if it does not require saving.
    *);

    precondition:
        (*
         * The gradesheet does not require saving.
         *)
        not (uws.Gradesheets[1].requires_saving);

    postcondition:
        (*
         * The current gradesheet is deleted from the workspace.  The remaining
         * gradesheets, if any, are shifted in position in the list one position
         * earlier.
         *)
        (not (uws.Gradesheets[1] in uws'.Gradesheets)) and
        (#(uws'.Gradesheets) = #(uws.Gradesheets) - 1) and
        (forall (i:integer | (i >= 1) and (i < #(uws.Gradesheets)))
            uws'.Gradesheets[i] = uws.Gradesheets[i+1];
        );

  end FileClose;

operation FileSave is
    inputs: fs:FileSpace, uws:UserWorkSpace;
    outputs: fs':FileSpace, uws':UserWorkSpace;

    description: (*
        If the gradesheet in the given workspace requires saving, save it in the
        given file space.
    *);

    precondition:
        (*
         * The given workspace requires saving.  Also, there is a writable
         * file of the current workspace filename in the given FileSpace.  Note
         * that the only way the current file could be unwritable is through an
         * external change to the file space since the file was opened by the
         * Grader Tool.  Note further that this precondition disallows the
         * case where the current gradesheet file has been externally deleted
         * since it was opened by the Grader tool.  That is, the file must
         * both exist and be writable at the time the save is attempted.
         *)
        (uws.Gradesheets[1].requires_saving)

            and

        (exists (file in fs)
            (file.name = uws.Gradesheets[1].file.name) and
            (file.permissions.is_writable));

    postcondition:
        (*
         * There is a Grader-type file in the resulting FileSpace containing
         * the current workspace gradesheet as its file data.  In the resulting
         * workspace, the requires saving indicator and is false.
         *)
        (exists (file in fs')
            (file.name = uws'.Gradesheets[1].file.name) and
            (file.permissions.is_writable) and
            (file.file_type?grader_type) and
            (not uws'.Gradesheets[1].requires_saving)
        );
  end FileSave;

end File;